package {
    import com.bit101.hungryai.Food;
    import com.bit101.hungryai.Skeeter;
    
    import flash.display.MovieClip;
    import flash.display.Stage;
    import flash.display.StageScaleMode;
    import flash.events.Event;
    import flash.util.trace;
    
    public class HungryAI extends MovieClip {
        private var numSkeeters:int = 20;
        private var skeeters:Array;
        private var food:Food;
        
        public function HungryAI() {
            stage.align = "TL";
            stage.scaleMode = StageScaleMode.NO_SCALE;
            
            skeeters = new Array();
            
            // create just one food
            food = new Food();
            food.x = stage.stageWidth / 2;
            food.y = stage.stageHeight / 2;
            addChild(food);
            
            // create a whole bunch of skeeters,
            // initialize them, and put them on stage
            for(var i:int = 0; i < numSkeeters; i++)
            {
                var skeeter:Skeeter = new Skeeter();
                // set initial state
                skeeter.changeState(LookForFoodState.getInstance());
                skeeter.x = Math.random() * stage.stageWidth;
                skeeter.y = Math.random() * stage.stageHeight;
                skeeter.setFood(food);
                addChild(skeeter);
                skeeters.push(skeeter);
            }
            
            
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
        
        public function onEnterFrame(event:Event):void
        {
            // simple. just update everything.
            for(var i:int = 0; i < numSkeeters; i++)
            {
                skeeters[i].update();
            }
            food.update();
        }
    }
}